※※※※※※※※※※※※※※
※※※ TTL_ログイン.ttl ※※
※※※※※※※※※※※※※※
;*****************************
;■ 対象サーバ情報
;*****************************
strdim Server_NAME 4
Server_NAME[0] = '【ｻｰﾊﾞ名】'
Server_NAME[1] = '【ｻｰﾊﾞ名】'
Server_NAME[2] = '【ｻｰﾊﾞ名】'
Server_NAME[3] = '【ｻｰﾊﾞ名】'
;-----------------------------
strdim Server_IPaddress 4
Server_IPaddress[0] = '192.168.0.xx'
Server_IPaddress[1] = '192.168.0.xx'
Server_IPaddress[2] = '192.168.0.xx'
Server_IPaddress[3] = '192.168.0.xx'
;-----------------------------
strdim Server_USER 4
Server_USER[0] = '【ﾕｰｻﾞID】'
Server_USER[1] = '【ﾕｰｻﾞID】'
Server_USER[2] = '【ﾕｰｻﾞID】'
Server_USER[3] = '【ﾕｰｻﾞID】'
;-----------------------------
strdim Server_PASS 4
Server_PASS[0] = '【ﾊﾟｽﾜｰﾄﾞ】'
Server_PASS[1] = '【ﾊﾟｽﾜｰﾄﾞ】'
Server_PASS[2] = '【ﾊﾟｽﾜｰﾄﾞ】'
Server_PASS[3] = '【ﾊﾟｽﾜｰﾄﾞ】'
;*****************************
;■ サーバ選択画面
;*****************************
getdir TTL_Path
strconcat TTL_Path '\TTL_SSH.ttl'
include TTL_Path
;*****************************
;■ ログイン後にコマンド実行
;*****************************
pause 1
sendln
sendln
wait '$' '#'
sendln
send 'date ; uname -n ; id'
sendln
sendln
※※※※※※※※※※※※※※
※※※※TTL_SSH.ttl ※※※※
※※※※※※※※※※※※※※
;*****************************
;■ 選択画面の表示
;-----------------------------
listbox '『対象を選択してください』' '【サーバ名】' Server_NAME
;-----------------------------
;■ 選択したresult値を取得
if result >= 0 then
paramIP = Server_IPaddress[result] ;; ■ IPアドレス
paramUSER = Server_USER[result] ;; ■ ユーザ名
paramPASS = Server_PASS[result] ;; ■ パスワード
LOG_File = Server_NAME[result] ;; ■ ログファイル名
else
end
endif
;*****************************
;■ SSHログイン情報
;-----------------------------
;■ SSHの認証方式の設定
;-----------------------------
paramAUTH = 'password' ;; ■ 認証方式の値
;-----------------------------
;■ INIファイルのパス設定
;-----------------------------
getdir macroDIR ;; ■ 現在のパス取得
strconcat macroDIR '\TERATERM.INI' ;; ■ INIファイル名
paramINI = macroDIR ;; ■ INIファイルの値
;*****************************
;■ SSH接続コマンド編集
;-----------------------------
LoginSSH = paramIP ;; ■ IPアドレス
strconcat LoginSSH ':22 /ssh /2 /auth=' ;; ■ 認証方式オプション
strconcat LoginSSH paramAUTH ;; ■ 認証方式の値
strconcat LoginSSH ' /user=' ;; ■ ユーザ名オプション
strconcat LoginSSH paramUSER ;; ■ ユーザ名の値
strconcat LoginSSH ' /passwd=' ;; ■ パスワードオプション
strconcat LoginSSH paramPASS ;; ■ パスワードの値
strconcat LoginSSH ' /F=' ;; ■ INIファイルオプション
strconcat LoginSSH paramINI ;; ■ INIファイルの値
;*****************************
;■ LOGファイルの設定
;-----------------------------
getdir LOG_Path
strconcat LOG_Path '\LOG\'
getdate LogDate '_%Y%m%d-%H%M%S.log'
strconcat LOG_File LogDate
strconcat LOG_Path LOG_File
;*****************************
;■ SSH接続ログイン
;-----------------------------
;; messagebox LOG_Path 'デバッグ用メッセージ'
connect LoginSSH
logopen LOG_Path 0 0
;*****************************
;■ タイトル設定
;-----------------------------
settitle LOG_Path
PR
